Автоматизация сборки проекта на WordPress. WP CLI + AppleScript + MAMP PRO.

/bin/bash -c "$(curl -fsSL https://raw.githubusercontent.com/Homebrew/install/HEAD/install.sh)"

brew install wp-cli

wp --version

--PROPERTIES
property projectsUrl : "/Users/user_name/Desktop/repo/"
property dbName : "wp_test"
property projectName : "wp.test.loc"
property themePath : "/wp-content/themes/my_mega_theme/"
property themeNameInRepo : "my_mega_theme-lr-mix"
property themeName : "my_mega_theme"
property adminPass : "lUn8wdf4Gx"
property siteTitle : "Site_Name" --no sapaces, please

--VARIABLES
set appStatus to "OK"

--UTILS
on ProcessRunning(processName)
	set AppleScript's text item delimiters to "\\|"
	set theExpression to processName as string
	set AppleScript's text item delimiters to ""
	set isRunning to every paragraph of (do shell script "ps -acwx -o command | grep -ix " & quoted form of theExpression & " || echo 'false'")
	
	if isRunning contains "false" then
		return false
	else
		return true
	end if
end ProcessRunning

--MAMP PRO running test
if application "MAMP PRO" is not running then
	set theDialogText to "А MAMP запустить не забыл?"
	display dialog theDialogText
	--> Result: {button returned:"OK"}
	
	set appStatus to "FAIL"
	
else
	set apacheRunning to my ProcessRunning("httpd")
	set mysqlRunning to my ProcessRunning("mysqld")
	
	if (not apacheRunning and not mysqlRunning) then
		set theDialogText to "По ходу MAMP работает, но не запущен сервер. Надо бы запустить"
		display dialog theDialogText
		--> Result: {button returned:"OK"}
		
		set appStatus to "FAIL"
	end if
end if


if appStatus is "OK" then
	--TERMINAL'
	if application "Terminal" is running then
		tell application "Terminal"
			quit
		end tell
	end if
	
	delay 1
	
	tell application "Terminal"
		
		
		--INIT
		activate
		set mainID to id of front window
		close (every window whose id ≠ mainID)
		
		
		--CREATE DB
		do script "/Applications/MAMP/Library/bin/mysql --host=localhost -uroot -proot;" in window 1
		do script "CREATE DATABASE " & dbName & ";" in window 1
		do script "QUIT;" in window 1
		
		delay 1
		
		--MAKE PROJECT FOLDER
		do script "cd " & projectsUrl in window 1
		do script "mkdir -p " & projectName in window 1
		do script "cd " & projectName in window 1
		
		
		--INSTALL WP
		do script "wp core download" in window 1
		do script "wp config create --dbname=" & dbName & " --dbuser='root' --dbpass='root' --dbhost='localhost' --dbprefix='wp_'" in window 1
		do script "wp core install --url='http://" & projectName & ":8899'  --title=" & siteTitle & " --admin_user='sb_admin' --admin_password=" & adminPass & " --admin_email='kykyky@bk.ru'" in window 1
		do script "wp language core install ru_RU" in window 1
		do script "wp site switch-language ru_RU" in window 1
		
		
		--SET WP THEME
		do script "cp -a " & projectsUrl & "_THEMES/" & themeNameInRepo & "/. " & projectsUrl & projectName & themePath in window 1
		do script "cd " & projectsUrl & projectName in window 1
		do script "wp theme activate " & themeName in window 1
		do script "wp theme delete $(wp theme list --status=inactive --field=name)" in window 1
		do script "wp plugin delete $(wp plugin list --status=inactive --field=name)" in window 1
		
		--do script "killall Terminal" in window 1
		
		
		--WAIT FOR COMPLETE	
		repeat
			delay 1
			if application "Terminal" is not running then
				
				--SHOW WEB SITE
				--tell application "Google Chrome"
				--	activate
				--	open location "http://" & projectName & ":8899"
				--end tell
				
				--DONE NOTIFICATION
				display notification "Создал проект " & projectName with title "Я сделял, хозяин!" subtitle "Создание проекта прошло успешно"
				
				quit
				exit repeat
				
			end if
		end repeat
		
	end tell
end if

--PROPERTIES
property projectsUrl : "/Users/user_name/Desktop/repo/"
property dbName : "wp_test"
property projectName : "wp.test.loc"

--VARIABLES
set appStatus to "OK"

--UTILS
on ProcessRunning(processName)
	set AppleScript's text item delimiters to "\\|"
	set theExpression to processName as string
	set AppleScript's text item delimiters to ""
	set isRunning to every paragraph of (do shell script "ps -acwx -o command | grep -ix " & quoted form of theExpression & " || echo 'false'")
	
	if isRunning contains "false" then
		return false
	else
		return true
	end if
end ProcessRunning

--CONFIRM DELETING
set theDialogText to "Точно хочешь удалить проект " & projectName & "?"
display dialog theDialogText buttons {"Нет!", "Удалить"} default button "Удалить" cancel button "Нет!"
--> Result: {button returned:"Нет!"}

--MAMP PRO running test
if application "MAMP PRO" is not running then
	set theDialogText to "А MAMP запустить не забыл?"
	display dialog theDialogText
	--> Result: {button returned:"OK"}
	
	set appStatus to "FAIL"
	
else
	set apacheRunning to my ProcessRunning("httpd")
	set mysqlRunning to my ProcessRunning("mysqld")
	
	if (not apacheRunning and not mysqlRunning) then
		set theDialogText to "По ходу MAMP работает, но не запущен сервер. Надо бы запустить"
		display dialog theDialogText
		--> Result: {button returned:"OK"}
		
		set appStatus to "FAIL"
	end if
end if


if appStatus is "OK" then
	--TERMINAL
	if application "Terminal" is running then
		tell application "Terminal"
			quit
		end tell
	end if
	
	delay 1
	
	tell application "Terminal"
		
		--INIT
		activate
		set mainID to id of front window
		close (every window whose id ≠ mainID)
		
		--REMOVE DB
		do script "/Applications/MAMP/Library/bin/mysql --host=localhost -uroot -proot" in window 1
		do script "DROP DATABASE " & dbName & ";" in window 1
		do script "QUIT;" in window 1
		
		--MAKE PROJECT FOLDER
		do script "rm -rf " & projectsUrl & projectName in window 1
		
		--do script "killall Terminal" in window 1
		
		--WAIT FOR COMPLETE	
		repeat
			delay 1
			if application "Terminal" is not running then
				
				--DONE NOTIFICATION
				display notification "Удалил проект " & projectName with title "Я сделял, хозяин!" subtitle "Удаление проекта прошло успешно"
				
				quit
				exit repeat
				
			end if
		end repeat
		
	end tell
	
end if

wp --info

PHP_VERSION=$(ls /Applications/MAMP/bin/php/ | sort -n | tail -1)
export PATH=/Applications/MAMP/bin/php/${PHP_VERSION}/bin:$PATH

property runVSCode : true
property runChrome : true
property runMAMP : true
property runTelegram : true
property openProjectfolder : true


-- UTILS
on RunApp(appName)
	if application appName is not running then
		tell application appName
			activate
		end tell
	end if
end RunApp


-- RUN APPLICATIONS
if runVSCode then
	RunApp("Visual Studio Code")
end if

delay 1

if runChrome then
	RunApp("Google Chrome")
end if

delay 1

if runMAMP then
	RunApp("MAMP PRO")
end if

delay 1

if runTelegram then
	RunApp("Telegram Desktop")
end if


-- OPEN FOLDERS
if application "Finder" is not running then
	tell application "Finder"
		activate
	end tell
end if

delay 1

tell application "Finder"
	open ("/Users/user_name/Desktop/repo/" as POSIX file)
end tell